Elegir un sistema de calificación en Educación de personas adultas

Cada centro, cada departamento o cada equipo educativo debe establecer la forma concreta de calificar a los alumnos en las distintas evaluaciones.
Después de varias pruebas y de resolver los problemas que se presentaban hemos llegado a elaborar cinco fórmulas distintas para que cada equipo educativo pueda elegir la que más se ajusta a sus preferencias. Con el tiempo, en esta misma entrada, se incluirán las nuevas fórmulas que se vayan elaborando como respuesta a otros criterios.
El proceso para adoptar una de estas fórmulas es el siguiente:
1º.- Selecciona la celda donde se va a calcular la nota de la evaluación del primer alumno.
3º.- Elige la fórmula que prefieres.
2º.- Copia y pega la fórmula que has elegido en la celda.  Si lo has hecho bien, la fórmula aparecerá arriba y a la izquierda, en la barra de fórmulas

4º.- Comprueba que la fórmula funciona correctamente introduciendo algunas puntuaciones de prueba. Si no funciona, seguramente, será debido a que has añadido o suprimido filas y, en ese caso, los intervalos que se han establecido en las fórmulas no coinciden con los que tienes en tu hoja. Si es así tienes que preparar la fórmula para que se ajuste a tu herramienta cambiando los datos de las celdas que marcan el inicio y el fin de los intervalos.
5º.- Una vez que funcione tienes que: copiar > selecciona todas las celdas donde va la evaluación del resto de alumnos >pegado especial > solo fórmula.

EVALUACIÓN FINAL - EDUCACIÓN PERSONAS ADULTAS

Todos los estándares se ponderan de la misma forma:

=SI.ERROR((SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"s";L2:L76;">=0")+SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"n";L2:L76;">=0"))/(CONTAR.SI.CONJUNTO($D2:$D76;"s";L2:L76;">=0")*2+CONTAR.SI.CONJUNTO($D2:$D76;"n";L2:L76;">=0")*2)*10;"")

b.- Los estándares básicos son el 50% de la nota y el resto de estándares son el otro 50%:

=SI.ERROR(SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"s";L2:L76;">=0")/(CONTAR.SI.CONJUNTO($D2:$D76;"s";L2:L76;">=0")*2)*5+SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"n";L2:L76;">=0")/(CONTAR.SI.CONJUNTO($D2:$D76;"n";L2:L76;">=0")*2)*5;"")

c.- Los estándares básicos se ponderan el doble que los no básicos:

=SI.ERROR((SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"s";L2:L76;">=0")*2+SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"n";L2:L76;">=0"))/(CONTAR.SI.CONJUNTO($D2:$D76;"s";L2:L76;">=0")*4+CONTAR.SI.CONJUNTO($D2:$D76;"n";L2:L76;">=0")*2)*10;"")

d.-  Los estándares básicos se ponderan el triple que los no básicos:

=SI.ERROR((SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"s";L2:L76;">=0")*3+SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"n";L2:L76;">=0"))/(CONTAR.SI.CONJUNTO($D2:$D76;"s";L2:L76;">=0")*6+CONTAR.SI.CONJUNTO($D2:$D76;"n";L2:L76;">=0")*2)*10;"")

e.- Los estándares básicos se ponderan el cuádruple que los no básicos:

=SI.ERROR((SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"s";L2:L76;">=0")*4+SUMAR.SI.CONJUNTO(L2:L76;$D2:$D76;"n";L2:L76;">=0"))/(CONTAR.SI.CONJUNTO($D2:$D76;"s";L2:L76;">=0")*8+CONTAR.SI.CONJUNTO($D2:$D76;"n";L2:L76;">=0")*2)*10;"")